teleport_heartbeat.osl

Go to the documentation of this file.

 
 string VERSION_STRING = "2.0.0";
 
 float MINIMUM_HEARTBEAT_PERIOD = 0.1;

float DEFAULT_LOCATION_OFFSET = 2.0;
 
string CONFIG_NOTECARD_NAME = "brigadoon_teleporter.config";
 
string CONFIG_DESTINATIONS_NAME = "teleport_destinations.config";

string COMMENT_PREAMBLE = "//";

integer COMMENT_PREAMBLE_LENGTH = 2;

string DATABASE_INTERFACE = "DATABASE_INTERFACE";

string LOCATION_NAME = "LOCATION_NAME";

string LANDING_OFFSET = "LANDING_OFFSET";

string HEARTBEAT_PERIOD = "HEARTBEAT_PERIOD";

string FRONT_OFFSET_ANGLE = "FRONT_OFFSET_ANGLE";

string LOCATION_TYPE = "LOCATION_TYPE";

string GROUP_LOCATION     = "GROUP";

string ANONYMOUS_UNIT = "ANONYMOUS";

 string REMOTE_UPDATE = "REMOTE_UPDATE";
 
 
 string EXTENDED_LOCAL = "EXTENDED_LOCAL";
 
string REGION_LOCATION    = "REGION";

string WORLD_LOCATION     = "WORLD";

string METAVERSE_LOCATION = "METAVERSE";

integer GROUP_FLAG     = 1;

integer REGION_FLAG    = 2;

integer WORLD_FLAG     = 4;

integer METAVERSE_FLAG = 8;
 
integer ANONYMOUS_FLAG = 16;

integer REMOTE_UPDATE_FLAG = 64;

integer EXTENDED_LOCAL_FLAG = 32;

integer LOCATION_MASK = ~(GROUP_FLAG + REGION_FLAG + WORLD_FLAG + METAVERSE_FLAG);
 

string LOCALITY_GROUP = "LOCALITY_GROUP";

float TIMER_OFF = 0.0;

float MINIMUM_HEARTBEAT_INTERVAL = 600;

float MINIMUM_OFFSET = 0.5;

float MAXIMUM_OFFSET = 10.0;
 
string location_world;

string location_name;
 
string locality_group = "null";

string location_region;

float landing_offset =  DEFAULT_LOCATION_OFFSET;

key heartbeat_key;

list destination_data;
 
float front_offset_angle = 0.0;

string database_interface;

float heartbeat_period;

list teleport_list;

integer location_info = 0;

integer version_number;

list destination_preamble    = [
                                    "// Filename: teleport_destinations.config",
                                    "// Version: " + VERSION_STRING,
                                    "// Date: " + llGetDate() + " UTC",
                                    "// Author: River Drifter ( river-drifter@aussiebroadband.com.au )",
                                    "// Email: river-drifter@aussiebroadband.com.au",
                                    "// Licence: Creative Commons Attribution Share Alike 4.0 International or better",
                                    "//",
                                    "// This destination file is created specifically for this teleporter in the region where",
                                    "// it was located. If the teleporter is moved to another region, it must be reset to",
                                    "// generate a new version of this file.",
                                    "//",
                                    "// *NOTE*: This file is periodically recreated by the Teleporter Heartbeat script.",
                                    "// All entries place here manually will be lost when the file is recreated. If you",
                                    "// wish do testing with manual entries, disable the heartbeat script for the duration.",
                                    "//=========================================================="
                                ];

rdProcessFailureMessage(string FailureMessage)
{
    string failure_message;
    
    list status = llParseString2List(FailureMessage, [":"], ["\n"]);  
    string failure_type = llList2String(status, 0);
    
    // Explain why the Teleporter could not be automatically processed
    if (failure_type == "BANNED")
    {
        failure_message  = "Teleporters owned by user " + llList2String(status, 1) + " are not permitted to";
        failure_message += " add teleporters to the database, update teleporter information or update teleporter destinations.";
    }
    
    // Explain that the Updating of the Datasbase using the Heartbeat message has failed.
    else if (failure_type == "UPDATE")
    {
        failure_message  = "The updating of the Teleporter's information in the database has unexpectedly failure with the error message: ";
        failure_message += llList2String(status, 1);
    }
    
    // Explain that the Insertion into the Database using the Heartbeat message has failed
    else if (failure_type == "INSERT")
    {
        failure_message  = "The insertion of a new teleporter's information into the database has failed unexpectedly with the error message: ";
        failure_message += llList2String(status, 1);
    }
    
    // Explain that the Insertion/update failed because the Teleporter name was already in use and duplicate names are not allowed.
    else if (failure_type == "NAME_MATCH")
    {
        failure_message  = "Unable to insert the new teleporter's information into the database because the Teleporter's Name is already in use ";
        failure_message += "by another teleporter located at " +  llList2String(status, 1);
    }
    
    // Explain that a failure in extracting the destination list for this Teleporter
    else if (failure_type == "EXTRACT")
    {
        failure_message  = "The extraction of the list of teleporter destinations has failed unexpectedly with the error message: ";
        failure_message += llList2String(status, 1);
    }
    
    //  Explain that Teleporters from world's outside of this one cannot be added automatically added.
    else if (failure_type == "INVADER")
    {
        failure_message = "Teleports from home world '" + llList2String(status, 1) + "' are not permitted to ";
        failure_message += " add teleporters to the database, update teleporter information or update teleporter destinations.";        
    }
    
    // Tell the person what to do if there was an error.
    failure_message += "\n If you wish to report this as an error please send this message to River Drifter with details of what happened and when.\n";
    llSay(0, failure_message); 
}

integer rdSetAnonType(string ValueObject, integer InfoInteger)
{
    if (llToUpper(ValueObject) == "YES") InfoInteger |= ANONYMOUS_FLAG; else InfoInteger &= ~ANONYMOUS_FLAG;
    
    return InfoInteger;
}

integer rdSetRemoteUpdate(string ValueObject, integer InfoInteger)
{
    if (llToUpper(ValueObject) == "YES") InfoInteger |= REMOTE_UPDATE_FLAG; else InfoInteger &= ~REMOTE_UPDATE_FLAG;
    return InfoInteger;
}

integer rdSetExtendedLocal(string ValueObject, integer InfoInteger)
{
    if (llToUpper(ValueObject) == "TRUE") InfoInteger |= EXTENDED_LOCAL_FLAG; else InfoInteger &= ~EXTENDED_LOCAL_FLAG;    
    return InfoInteger;
}

integer rdGetVersionNumber(string VersionString)
{
    integer version;
    
    list versions = llParseString2List(VersionString, ["."], []);
    version = (integer)llList2String(versions,2) + ((integer)llList2String(versions,1) * 100) + ((integer)llList2String(versions,0) * 10000);
    
    return version;
}

integer rdSetLocationType(string ValueString, integer LocationInfo)
{
    integer location_buffer = 0;
    
    // Cut the Location Types out of the Location Info
    LocationInfo &= LOCATION_MASK;
    
    // Break the Value String into Components
    list  type_component = llParseString2List(ValueString, [","], []);
    integer list_size = llGetListLength(type_component);
    integer index = 0;
    
    // Process each LocationType
    for (; index < list_size; ++index)
    {
        string location_type = llStringTrim(llList2String(type_component, index), STRING_TRIM);
        if (location_type == GROUP_LOCATION) location_buffer += GROUP_FLAG;
        else if (location_type == REGION_LOCATION) location_buffer += REGION_FLAG;
        else if (location_type == WORLD_LOCATION) location_buffer += WORLD_FLAG;
        else if (location_type == METAVERSE_LOCATION) location_buffer += METAVERSE_FLAG;
    }
    
    // Put intp the Location Information
    LocationInfo |= location_buffer;
    
    return LocationInfo;
}
 
string rdAdjustPosition(string Line)
{
    string world;
    string region;
    string output_line;
    vector landing;
    vector look_at;
    
    //llSay(0,Line);
    
    // Split the Entry into components    
    list components = llParseString2List(Line, ["|"], []);
    
    string name = components[0];
    vector init_pos = (vector)components[1];
    rotation initial_rot = (rotation)components[2];
    vector offset_info = (vector)components[3];
    string location_group = components[4];
    integer address_type = (integer)components[5];
 
    if (address_type == 2)
    {
        region = components[6];
        world = components[7];
    }
    else if (address_type == 1)
    {
        region = components[6];
        world = location_world;
    }
    else if (address_type == 0)
    {
        region = location_region;
        world = location_world;
    }
    else
    {
        llSay(DEBUG_CHANNEL, "Format Error");
    }
    
    // Because of the Inherent limit of eight(8) elements when parsing a string
    // three (3) of the numeric items were condensed into a vector to overcome this
    // problem.
    float offset_distance = (float)offset_info.x;
    float look_angle = (float)offset_info.y;
    integer location_information = (integer)offset_info.z;
 
    // Determine the Landing Position by adding offset to the Teleporter's Location
    // The offset is set negative to move to it "back to the front" of the Teleporter Object
    landing = init_pos + llRot2Fwd(initial_rot) * -offset_distance;
    
    vector temp = llRot2Euler(initial_rot * llAxisAngle2Rot(<0,0,1>, look_angle));
    look_at = <llCos(temp.z), llSin(temp.z), 0.0>;
    
    // Create the String to be stored in the Teleport Destination Notecard.
 
    output_line  = name + "|" + world + "|" + region + "|";
    output_line += (string)landing + '|' + (string)look_at + '|';
    output_line += (string)location_information + '|';          
    output_line += location_group + "\n";
    
    return output_line;
}

rdSaveNewTeleportNotecard(list teleport_list)
{
    // Add the Preamble Text before the List of Destinations
    teleport_list = destination_preamble + teleport_list;
       
    // Delete the Existing Teleporter Destination Notecard, if it exists
    integer count = llGetInventoryNumber(INVENTORY_NOTECARD);
    integer index = 0;
    for (; index < count; ++index)
    {
        if (llGetInventoryName(INVENTORY_NOTECARD, index) == CONFIG_DESTINATIONS_NAME)
        {
            llRemoveInventory(CONFIG_DESTINATIONS_NAME);
            index = count;  // Ext Loop
        }
    }
    
    // Write the Teleport List to a New Notecard
    osMakeNotecard(CONFIG_DESTINATIONS_NAME, teleport_list);
}

rdSendHeartbeatMessage()
{
    // Do a cursory Check that the configuration has been set up
    if ((location_name != "") && (database_interface != ""))
    {
        // Reset the Data received for the Database
        teleport_list = [];
        integer teleport_list_started = FALSE;
        
        key teleporter_key = llGetKey();
        list details = llGetObjectDetails(teleporter_key, [OBJECT_POS, OBJECT_ROT, OBJECT_OWNER, OBJECT_GROUP]);
        
        string heartbeat_message = database_interface + "?command=heartbeat"
                                + "&name="         + llEscapeURL(location_name)
                                + "&key="          + teleporter_key
                                + "&position="     + osReplaceString(llList2String(details, 0), " ", "", -1, 0)
                                + "&rotation="     + osReplaceString(llList2String(details, 1), " ", "", -1, 0)
                                + "&owner="        + llList2String(details, 2)
                                + "&group="        + llList2String(details, 3)
                                + "&world="        + location_world
                                + "&region="       + llGetRegionName()
                                + "&offset="       + (string)landing_offset
                                + "&offsetangle="  + (string)front_offset_angle
                                + "&locationinfo=" + (string)location_info
                                + "&vernum="       + (string)version_number
                                + "&localitygroup=" + locality_group;
        heartbeat_key = llHTTPRequest(heartbeat_message, [HTTP_BODY_MAXLENGTH,16384], [""]);      
    }
    else
    {
        llSay(DEBUG_CHANNEL, "Either the location_name or database_interface are undefined! Teleporter " + location_name + " has been disabled");
        llSetScriptState(llGetScriptName(), FALSE); 
    }
} 
 
default
{
    state_entry()
    { 
 
        location_world  = llGetSubString(osGetGridHomeURI(), 7, -1);
        location_region = llGetRegionName();
        version_number  = rdGetVersionNumber(VERSION_STRING);
        
        // Read the Configuration File into a List of Lines
        string config = osGetNotecard(CONFIG_NOTECARD_NAME);
        list config_data = llParseString2List(config, ["\n"], []);
        
        // Process each line in the Configuration Data
        integer index = 0;
        integer list_length = llGetListLength(config_data);
        for (; index < list_length; ++index)
        {
            // Trim line of  Leading and Trailing Spaces
            string trimmed_line = llStringTrim(llList2String(config_data, index), STRING_TRIM);
            
            // Only Process lines that are not a comment line or blank
            if ( (llGetSubString(trimmed_line, 0, COMMENT_PREAMBLE_LENGTH - 1) != COMMENT_PREAMBLE) && (trimmed_line != "") )
            {
                // Parse Line for a Configuration Field.
                list key_value = llParseString2List(trimmed_line, ["="], []);
                 
                // Fold the Trimmed Key into upper case, to eliminate errors where the case is wrong in the config file.
                string key_object = llToUpper(llStringTrim(llList2String(key_value, 0), STRING_TRIM));
                 
                // Trim the Value to remove leading and training spaces
                string value_object = llStringTrim(llList2String(key_value, 1), STRING_TRIM);
                 
                // Process the Key-Value Pairs to Set Configuration
                if (key_object == DATABASE_INTERFACE)       database_interface = value_object;
                else if (key_object == LOCATION_NAME)       location_name = value_object;
                else if (key_object == LANDING_OFFSET)      landing_offset = (float)value_object;
                else if (key_object == HEARTBEAT_PERIOD)    heartbeat_period = (float)value_object * 3600.0; // Convert hours to seconds
                else if (key_object == FRONT_OFFSET_ANGLE)  front_offset_angle = (float)value_object;
                else if (key_object == LOCATION_TYPE)       location_info  = rdSetLocationType(llToUpper(value_object), location_info); 
                else if (key_object == LOCALITY_GROUP)      locality_group = llEscapeURL(value_object);
                else if (key_object == ANONYMOUS_UNIT)      location_info  = rdSetAnonType(value_object, location_info);
                else if (key_object == REMOTE_UPDATE)       location_info  = rdSetRemoteUpdate(value_object, location_info);
                else if (key_object == EXTENDED_LOCAL)      location_info  = rdSetExtendedLocal(value_object, location_info);
            }
            
            // Check that the Heartbeat Period is equal to or greater than the Minimum
            if (heartbeat_period < MINIMUM_HEARTBEAT_INTERVAL) heartbeat_period = MINIMUM_HEARTBEAT_INTERVAL;
            
            // Check the Landing Offset values against limits
            if (landing_offset < MINIMUM_OFFSET) landing_offset = MINIMUM_OFFSET; else if (landing_offset > MAXIMUM_OFFSET) landing_offset = MAXIMUM_OFFSET;
        } 
 
        // Send out an Initial Heartbeat Message
        rdSendHeartbeatMessage();
        
        // Start the Heatbeat Timer, but first check that the heartbeat period would no result in flooding of the database.
        if (heartbeat_period < MINIMUM_HEARTBEAT_PERIOD) heartbeat_period = MINIMUM_HEARTBEAT_PERIOD;
        llSetTimerEvent(heartbeat_period);    
    }

    http_response(key RequestId, integer Status, list Metadata, string Body)
    {
        list teleport_list;
 
        // Only respond to the Heartbeat Request
        if (RequestId == heartbeat_key)
        {
            // Check to see if the Request was a Success
            if (Status != 200)
            {
                llSay(DEBUG_CHANNEL, "Heartbeat Request Failed with error " + (string)Status);
            }
            else
            {
                // Split into a list for easier processing
                list input_list = llParseString2List(Body, ["\n"], []);
                
                // Step thought the list a line at a time
                integer index = 0;
                integer input_list_started = FALSE;
                integer list_count = llGetListLength(input_list);
                
                string line;
                do
                { 
                    // Extract the Line
                    line = llList2String(input_list, index);
                    
                    // Start the Teleport Notecard             
                    if (line == "EXTRACT_LIST=START") input_list_started = TRUE;
                    
                    // End if you find the END FLAG by setting index to the end
                    else if (line == "EXTRACT_LIST=END")
                    {
                        index = list_count;
                        input_list_started = FALSE;
                    }
 
                    // Extract the Data Line & Process
                    else if (input_list_started == TRUE)
                    {
                        string updated_line = rdAdjustPosition(line);
                        teleport_list += updated_line;
                    }
                    
                    // Check if this is a status message of Pin Setting Message
                    else
                    {
                        list status_list = llParseString2List(line, ["="], []);
                        string key_string = llList2String(status_list, 0);
                        string value_string = llList2String(status_list, 1);
                        if (key_string == "FAILURE") rdProcessFailureMessage(value_string);
                        else if (key_string == "ACCESS_PIN") llSetRemoteScriptAccessPin((integer)value_string);
                    }
                    
                    // Add Destination to the Teleport Notecard
                }
                while ( ++index < list_count);
                
                // Replace the old Teleport Notecard with New One
                rdSaveNewTeleportNotecard(teleport_list);
            }
        } 
    }
    
    timer()
    {
        rdSendHeartbeatMessage();
    }
}