brigadoon_teleporter.osl

Go to the documentation of this file.

*! \file brigadoon_teleporter.osl
 *  \brief SCript to send a Heartbeat signal to the Teleport Database
 *  \version 1.2.0
 *  \date 25-December-2025
 *  \author River Drifter @ little-sense.au:9000
 *  \email river_drifter@aussiebroadband.com.au
 *
 *
 * NOTE: The file extension ".osl" indicates the script uses the Open Simulator Script
 * language (OSSL) and will not function in the Second Life environment. If the script
 * will function using just the Linden Scripting Language (LSL), it will have a a file
 * extension of ".lsl".
 *
 */
 
 string VERSION_STRING = "2.1.0";

string CONFIG_NOTECARD_NAME = "brigadoon_teleporter.config";

string CONFIG_DESTINATIONS_NAME = "teleport_destinations.config";

 integer LOCAL_TELEPORT_FORCE = TRUE;
 
string COMMENT_PREAMBLE = "//";

integer COMMENT_PREAMBLE_LENGTH = 2;

//string DATABASE_INTERFACE = "DATABASE_INTERFACE";

string LOCATION_NAME = "LOCATION_NAME";

float TIME_TO_DECIDE = 60.0;

float TIMER_OFF = 0.0;
 
string location_world;

string location_region;
 
/* \var list menu_list
 * \brief This of menu items to be shown
 *
 *
 */
list menu_list;

string location_name;

list destination_name;

list destination_world;

list destination_region;

list destination_location;

list destination_look_at;

list destination_loc_type;

list destination_group;
 
/* \var integer comms_channel
 * \brief Communication Channel used for the Menu
 *
 */
integer comms_channel;

integer listen_handle;
 
/* \var integer station_base
 * \brief offset in the destination list to start listing
 *
 */
integer station_base = 0;

integer station_list_size;

key last_user;

integer DIALOG_STATION_LIMIT = 9;

integer LOCAL_FLAG     = 1;

integer REGION_FLAG    = 2;

integer WORLD_FLAG     = 4;

integer METAVERSE_FLAG = 8;

integer ANONYMOUS_FLAG = 16;

 
integer EXTENDED_LOCAL_FLAG = 32;
integer REMOTE_UPDATE_FLAG = 64;

string rdLocInfo2String(integer LocationInfo, integer Index)
{
    string location_area = "";
    
    if ((LocationInfo & LOCAL_FLAG)          != 0) location_area = destination_group[Index];
    else if ((LocationInfo & REGION_FLAG)    != 0) location_area = destination_region[Index];
    else if ((LocationInfo & WORLD_FLAG)     != 0) location_area = destination_region[Index];
    else if ((LocationInfo & METAVERSE_FLAG) != 0) location_area = destination_world[Index];
    return " [" + location_area + "]";
}

integer rdCalcCommsChannel()
{
    integer random_value = 0x80000000 | (integer)llFrand(65536) | ((integer)llFrand(65536) << 16);
    return(random_value);
}

rdShowStationDialog(key User)
{
    list button_list;
    menu_list = [];
    
    // Add the back button if necessary
    if (station_base > 0) button_list += "<<"; else button_list += " ";
 
    // Add Done Button
    button_list += "DONE";
    
    // Add the Forward button, if necessary
    if (station_list_size > (station_base + DIALOG_STATION_LIMIT)) button_list += ">>"; else button_list += " ";
 
    // Now select the next (up to) nine (9) locatiions to display on the menu
    string menu_header = "Destinations Available from " + location_name + "\n";
    integer index;
    for (index = 0; index < DIALOG_STATION_LIMIT; ++index)
    {
        // Increase the menu number to match the actual number in the destination list, rather than menu number
        integer station_pos = index + station_base;
        if (station_pos < station_list_size)
        {
            // Get the type of location this destination is
            integer loc_info = (integer)llList2String(destination_loc_type, station_pos);
            
            // Get name of the destination and the type of location it is
            string item_name =  llUnescapeURL(llList2String(destination_name, station_pos)) + rdLocInfo2String(loc_info, station_pos);
            string index_string = (string)(station_pos + 1);
            
            // Add the Index, Name and location type to the menu header
            menu_header += "[" + index_string + "] " + item_name + "\n";
            
            // Add the index to the Buuton List to be displayed
            button_list += index_string;
            
            // Add the index to the line that will be scanned to match selections
            menu_list += index_string;
        }
        
        // If there aren't enough destinations to fill the nine (9) spaces use blanks
        else
        {
            // Add to the button list, but not the menu list as we don'r want matches to empty buttons
            button_list += " ";
        }
    }
    
    // Display the Dialog Menu
    llDialog(User, menu_header, button_list, comms_channel);
}

rdDoTeleport(key Agent, integer Index)
{
    // Get information about the Destination Location
    string the_world = llList2String(destination_world, Index);
    string the_region = llList2String(destination_region, Index);
    vector the_landing = (vector)llList2String(destination_location, Index);
    vector the_look_at = (vector)llList2String(destination_look_at, Index);
    
    // Update the current location of the Teleporter to select correct Teleportation Routine
    location_region = llGetRegionName();
    vector location_position = llGetPos();
    
    // If the Destination is not in this simulator, use a hop command to get there
    if (location_world != the_world)
    {
        osTeleportAgent(Agent, the_world + ":" + the_region, the_landing, the_look_at);
    }
    
    // If the Destination is not in this Region, use a Teleport command that specifies the Region
    else if (location_region != the_region)
    {
        osTeleportAgent(Agent, the_region, the_landing, the_look_at);
    }
    
    // If the destination is in this region, but not the landing location of this Teleporter us a local Teleport
    else if (location_position != the_landing)
    {
        osTeleportAgent(Agent, the_landing, the_look_at);
    }
} 

rdReadDestinationList()
{
    // Clear the Teleportation Lists
    destination_name = []; destination_world = []; destination_region = [];
    destination_location = []; destination_look_at = [];
    destination_loc_type = []; destination_group = [];
 
    // Loop though Destination Configuration File
    integer list_length = osGetNumberOfNotecardLines(CONFIG_DESTINATIONS_NAME);
    integer index = 0;
    do
    {
        // Get the Line
        string trimmed_line = llStringTrim(osGetNotecardLine(CONFIG_DESTINATIONS_NAME, index), STRING_TRIM);
 
        // Skip comment lines and blank lines
        if ( (llGetSubString(trimmed_line, 0, COMMENT_PREAMBLE_LENGTH - 1) != COMMENT_PREAMBLE) && (trimmed_line != "") )
        {    
            // Split the Teleportation Destination COmponents out.
            list destination      = llParseString2List(trimmed_line, ["|"], []);
            destination_name     += (string)destination[0];
            destination_world    += (string)destination[1];
            destination_region   += (string)destination[2];
            destination_location += (string)destination[3];
            destination_look_at  += (string)destination[4];
            destination_loc_type += (string)destination[5];
            destination_group    += (string)destination[6];
        }
    }
    while (++index < list_length);
    
    // Set the Size of teh Destination List for the Menu
    station_list_size = llGetListLength(destination_name);
}
 
rdInitialiseTeleporter()
{
        // Get the location of the current world 
        location_world = llGetSubString(osGetGridHomeURI(), 7, -1);
        
        // Get a Communications Channel. This can been overridden in the basic configuration
        comms_channel = rdCalcCommsChannel();
 
        // Read the Configuration File into a List of Lines
        string config = osGetNotecard(CONFIG_NOTECARD_NAME);
        list config_data = llParseString2List(config, ["\n"], []);
 
        // Process each line in the Configuration Data
        integer index = 0;
        integer list_length = llGetListLength(config_data);
        for (; index < list_length; ++index)
        {
            // Trim line of  Leading and Trailing Spaces
            string trimmed_line = llStringTrim(llList2String(config_data, index), STRING_TRIM);
            
            // Only Process lines that are not a comment line or blank
            if ( (llGetSubString(trimmed_line, 0, COMMENT_PREAMBLE_LENGTH - 1) != COMMENT_PREAMBLE) && (trimmed_line != "") )
            {
                // Parse Line for a Configuration Field.
                list key_value = llParseString2List(trimmed_line, ["="], []);
                 
                // Fold the Trimmed Key into upper case, to eliminate errors where the case is wrong in the config file.
                string key_object = llToUpper(llStringTrim(llList2String(key_value, 0), STRING_TRIM));
                 
                // Trim the Value to remove leading and training spaces
                string value_object = llStringTrim(llList2String(key_value, 1), STRING_TRIM);
                 
                // Process the Key-Value Pairs to Set Configuration
                if (key_object == LOCATION_NAME)   location_name = value_object; 
            }
            location_region = llGetRegionName();
        }
        
        // Initial Read of the teleportation Destnation List
        rdReadDestinationList();
}

default
{
    state_entry()
    {
        // Configure the Teleporter Script
        rdInitialiseTeleporter();
    }
    
    touch_start(integer TotalNumber)
    {
        // Remove any listen handlw
        llListenRemove(listen_handle);
        
        // Find out who touched this
        key user = llDetectedKey(0);
        
        // Get a new listener & show the Menu to the User
        listen_handle = llListen(comms_channel, "", user, "");
        rdShowStationDialog(user);
        
        // Set a time to ensure the menu is onolu active for a short time
        llSetTimerEvent(TIME_TO_DECIDE);
    }
    
    listen(integer Channel, string Name, key Id, string Message)
    {    
        integer found_index = -1;
        
        // If this was not the same user as before , reset to the start of the list
        if (Id != last_user)
        {
            station_base = 0;
            last_user = Id;
        }
 
        // Resert the Lilst to the start if the user is bombing out of the destionation selection
        if ((Message == "DONE") || (Message == "OK") || (Message == " ") || (Message == "Ignore"))
        {
            station_base = 0;
             return;
        }
 
        // If the selection is go back a page, reduce the base pointer by the number of items on a page
        if (Message == "<<")
        {
            station_base -= DIALOG_STATION_LIMIT;
            rdShowStationDialog(Id);
        }
        
        // If the selection is to go forward a page, increase the base pointer by the number of items on a page
        else if (Message == ">>")
        {
            station_base += DIALOG_STATION_LIMIT;
            rdShowStationDialog(Id);
        }
        
        // Othereise this ia s destination selection, so process it
        else
        {
            // Scan the list for a match
            integer index;
            for (index = 0; index < station_list_size; index++)
            {
                // Check if there is a match in the list of items displayed
                if (llList2String(menu_list, index) == Message)
                {
                    // Get the actual index into the entire list
                    found_index = index + station_base;
                    
                    // End the loop by going to the end index
                    index = station_list_size;
                }
            }
            
            // If a Match was found, Teleport the user to the Destination & reset Dialog parameters
            if (found_index != -1) {rdDoTeleport(Id, found_index); station_base = 0; last_user = NULL_KEY;}
        }
    }

    changed(integer Change)
    {
        // If the Inventory has changed, assume it will be the configuration notecard and/or destination notecard
        if (Change == CHANGED_INVENTORY)
        {
            // A Full Reset can cause a race condition when accessin the destination file controlled by the heartbeat script.
            // Give a bit of time to stop the script not being able to see the destination file immediately after it is rewritten.
            llSleep(0.25);
            
            // Reest script and reload Destinations
            rdInitialiseTeleporter();
        }
    }

    timer()
    {
        llListenRemove(comms_channel);
        llSetTimerEvent(TIMER_OFF);
        station_base = 0;
    }
}