project_list.osl

Go to the documentation of this file.

 
integer LastUnix;

integer DestValidCheck;
 
 
integer HasCheckedChanged;
integer NextCheck;
list DestinationsName;
list DestinationsLink;
list DestinationsLogo;
list DestinationsValid;
key CheckRequest;
 
integer DISPLAY_SIDE = 1;
integer COLUMNS = 3;
integer ROWS = 10;
integer ALT_ROWS = ROWS + 8;
string  SOURCE_URL = "https://www.little-sense.au/";
string  LOGO =  "images/Brigadoon_Logo_Small.png";
string  FAILURE = "images/question_mark.png";
string  NO_LOGO = "images/no_logo.png";
string  BLANK_LOGO = "images/blank_label.png";
string  FILE_DIRECTORY = "project_dynamic/";
//string  DEVELOPMENT_LIST = "project_dynamic/Destinations.txt";
//string  TASK_LIST =  "project_dynamic/task_list.txt";
 
UpdateTexture()
{
    integer TEXTURE_SIZE = 512;
    integer FONT_SIZE = (TEXTURE_SIZE / ROWS) / 5;
        
        
    string drawList;
    drawList = osSetPenSize(drawList, 1);
    drawList = osSetFontSize(drawList, FONT_SIZE);
 
    drawList = osMovePen(drawList, 0, 0);
    drawList = osSetPenColor(drawList, "Gray");
    drawList = osDrawFilledRectangle(drawList, TEXTURE_SIZE, TEXTURE_SIZE);
 
    integer x;
    integer y;
    string  Logo;
    
    // Step through the Column in the Display
    for (x = 0; x < COLUMNS; x++)
    {
        // Step through the rows in each column
        for (y = 0; y < ROWS; y++)
        {
            //Calculate the Cell Height and Vell Width
            integer CELL_HEIGHT = TEXTURE_SIZE / (ROWS + 8);
            integer CELL_WIDTH = TEXTURE_SIZE / COLUMNS;
            
            // Calculate the Location of the Top Left Cell
            integer xTopLeft = x * CELL_WIDTH;
            integer yTopLeft = y * CELL_HEIGHT;
 
            drawList = osSetPenColor(drawList, "White");
            drawList = osMovePen(drawList, xTopLeft, yTopLeft);
            drawList = osDrawRectangle(drawList, CELL_WIDTH, CELL_HEIGHT);
 
            integer index = (y + x * ROWS);
            string  cellName  = llList2String(DestinationsName, index);
            integer cellValid = llList2Integer(DestinationsValid, index);
 
            // If the cell is blank, use a blank logo as well
            string cellBbackground;
            if (cellName == "")
            {
                cellBbackground = "DarkGray";
                Logo = SOURCE_URL + BLANK_LOGO;
            }
            
            // If the Cell is not blank check if it is valid
            else
            {
                // If the Cell valid, give it a blue background and get its Logo
                if (cellValid)
                {
                    cellBbackground = "CadetBlue";
                    Logo = llList2String(DestinationsLogo, index);
                }
                
                // If the cell is isn't valid, make the background red & set the failed logo. 
                else
                {
                    cellBbackground = "IndianRed";
                    Logo = SOURCE_URL + FAILURE;
                }
            }
 
            // Fill the Cell with the Background Colour
            drawList = osSetPenColor(drawList, cellBbackground);
            drawList = osMovePen(drawList, xTopLeft + 2, yTopLeft + 2);
            drawList = osDrawFilledRectangle(drawList, CELL_WIDTH - 3, CELL_HEIGHT - 3);
 
            // Put the Logo onto into the adjacent cell/
            xTopLeft += 2;
            yTopLeft += 6;
            drawList = osSetPenColor(drawList, "Black");
            drawList = osMovePen(drawList, xTopLeft + 3, yTopLeft + 3);
            drawList = osDrawImage(drawList, 16,16, Logo);
            
            // Draw the Cell Name into the call
            drawList = osMovePen(drawList, xTopLeft + 20, yTopLeft - 1);
            drawList = osDrawText(drawList, cellName);
        }
    }
    
    // Use the Instructions on the drawList string to draw the cells
    osSetDynamicTextureDataBlendFace("", "vector", drawList, "alpha:false,width:" + (string)TEXTURE_SIZE + ",height:" + (string)TEXTURE_SIZE, FALSE, 1, 0, 255, DISPLAY_SIDE);
}
 
// *********** FOR DOXYGEN PROCESSING ONLY ****************
//default
default()
//************ REMOVE COMMENTS AFTER DOXYGEN PROCESSING ***
{

    state_entry()
    {
        string display_list;
        
        // Get the filename holding the information to be displayed
        string description = llToLower(llGetObjectDesc()) + ".txt";;
        
        // Create the URL and then send out a Request for the contents of the Data Text File
        llHTTPRequest(SOURCE_URL + FILE_DIRECTORY + description, [HTTP_METHOD, "GET"], "");
    }
    
    /* \fn http_response(key Dummy, integer Status, list Meta, string Body)
     * \brief Process the Data returned for the File by he HTTP Request
     * \param Dummy The response key from the HTTP Request
     * \param Status The Return Status from the HTTP Request
     * \param Meta The List of Meta Data returned from the HTTP Request
     * \param The contents of the Data file returned as a string
     *
     * This routine returns the contents of the data file.
     *
     */
    http_response(key Dummy, integer Status, list Meta, string Body)
    {
        DestinationsLogo = [];
        DestinationsName = [];
        DestinationsLink = [];
        DestinationsValid = [];
 
        // Split the Returned Data Text File into lines
        list Parse = llParseString2List(Body, ["\n"], []);
        
        // Step through each Line of Text
        integer i;
        for (i = 0; i < llGetListLength(Parse); ++i)
        {
            // If this isn't a blank Line, Process It
            if (llList2String(Parse, i) != "")
            {
                // Break the LIne into components
                list Line = llParseString2List(llList2String(Parse, i), ["="], []);
                
                // Only process if None of the Information is missing
                if (llGetListLength(Line) == 3 &&
                    llList2String(Line, 0) != "" &&
                    llList2String(Line, 1) != "" &&
                    llList2String(Line, 2) != "")
                {
                    DestinationsName = DestinationsName + [llList2String(Line, 0)];
                    DestinationsLink = DestinationsLink + [llList2String(Line, 1)];
                    DestinationsLogo = DestinationsLogo + [llList2String(Line, 2)];
                    
                    // Append a TRUE Flag to each line
                    DestinationsValid = DestinationsValid + [TRUE];
                }
            }
        }
        
        // Update the Texture and move into the Ready state.
        UpdateTexture();
        state Ready;
    }
 }
 
// *************** FOR DOXGEN PROCESSING ONLY ***********************
//state Ready
void Ready()
// *************** REMOVE AFTER DOXYGEN PROCESSING COMPLETE **********
 
{
    state_entry()
    {
        LastUnix = llGetUnixTime();
        DestValidCheck = 0;
        NextCheck = -1;
        HasCheckedChanged = FALSE;
        CheckRequest = llHTTPRequest(llList2String(DestinationsLink, DestValidCheck), [HTTP_METHOD, "GET"], "");
        llSetTimerEvent(10);
    }
    
    http_response(key Dummy, integer Status, list Meta, string Body)
    {
        if (Dummy != CheckRequest)
         {return;}
        llSetText(".", <1, 0, 0>, 1);
        if (Status == 200)
        {
            if (llList2Integer(DestinationsValid, DestValidCheck) == FALSE)
             {HasCheckedChanged = TRUE;}
            DestinationsValid = llListReplaceList(DestinationsValid, [TRUE], DestValidCheck, DestValidCheck);
        }
        else
        {
            if (llList2Integer(DestinationsValid, DestValidCheck) == TRUE)
             {HasCheckedChanged = TRUE;}
            DestinationsValid = llListReplaceList(DestinationsValid, [FALSE], DestValidCheck, DestValidCheck);
        }
        DestValidCheck = DestValidCheck + 1;
        if (DestValidCheck > llGetListLength(DestinationsLink) - 1)
        {
            if (HasCheckedChanged)
             {UpdateTexture();}
            NextCheck = llGetUnixTime();
            llSetText("", <1, 0, 0>, 1);
            return;
        }
        llSleep(1);
        CheckRequest = llHTTPRequest(llList2String(DestinationsLink, DestValidCheck), [HTTP_METHOD, "GET"], "");
    }
    
    timer()
    {
        if (LastUnix + 3600 * 4 < llGetUnixTime())
         {state default;}
        if (NextCheck != -1 && NextCheck + 90 < llGetUnixTime())
        {
            NextCheck = -1;
            DestValidCheck = 0;
            HasCheckedChanged = FALSE;
            CheckRequest = llHTTPRequest(llList2String(DestinationsLink, DestValidCheck), [HTTP_METHOD, "GET"], "");
        }
    }
    
    
    touch_start(integer Dummy)
    {
        vector point = llDetectedTouchST(0);
        integer face = llDetectedTouchFace(0);
        integer link = llDetectedLinkNumber(0);
 
//        if (link != LINK_ROOT)
//        {return;}
        if (point == TOUCH_INVALID_TEXCOORD)
         {return;}
        if (face != DISPLAY_SIDE)
         {return;}
 
        //integer y = (ALT_ROWS - 1) - llFloor(point.y * ALT_ROWS);
        integer y = (ROWS - 1) - llFloor(point.y * ROWS);
        integer x = llFloor(point.x * COLUMNS);
        integer index = (y + x * ROWS);
        
        if (llList2String(DestinationsLink, index) == "")
         {return;}
        
        if (llList2Integer(DestinationsValid, index) == TRUE)
        {
             key id = llDetectedKey(0);
             string info = "Dummy Information";
             llLoadURL(id, info, llList2String(DestinationsLink, index));
        }
        else
         {
             llDialog(llDetectedKey(0), "This link is invalid.", ["Ok"], -5);
         }
    }
}